Hola a todos,
Este va a ser un post un poco más elaborado de lo habitual. Vamos a crear un cuadro de seguimiento de proyectos en Power Apps que nos permitirá visualizar el avance de cada proyecto mediante barras de progreso dinámicas, así como consultar y modificar el estado de sus tareas.
Para ello, vamos a trabajar con dos listas de SharePoint, PROYECTOS y TAREAS, que estarán relacionadas mediante el campo CodigoProyecto.


y a continuación vamos a abrir nuestra Power Apps y crear los siguientes elementos:
- Una galería vertical (Gallery1): para mostrar los proyectos y sus correspondientes barras de progreso.
- Una segunda galería vertical (galTareas): para mostrar las tareas del proyecto seleccionado.
- Dos rectángulos (rectFondoBarra y rectBarraAvance): dentro de la galería de proyectos, que utilizaremos para construir las barras de progreso dinámicas.
- Varias etiquetas (Label): para mostrar el nombre de los proyectos, las tareas, los porcentajes de avance y los indicadores generales.
- Un desplegable (ddEstado): dentro de la galería de tareas, que nos permitirá modificar el estado de cada una de ellas.
- Un botón (btnActualizar): para actualizar los datos de SharePoint.
También añadiremos algunos elementos adicionales para dar formato a nuestra aplicación, como la cabecera y las tres tarjetas que mostrarán el número de proyectos, las tareas completadas y el porcentaje de avance global.
Lo primero que vamos a hacer es conectar nuestra aplicación a las dos listas de SharePoint, PROYECTOS y TAREAS.
Para trabajar con los datos y realizar los cálculos de una forma más sencilla, vamos a crear dos colecciones (colProyectos y colTareas). De esta manera, podremos realizar los filtros y recuentos necesarios directamente sobre las colecciones, evitando los problemas de delegación en estos cálculos.
Para ello, seleccionamos App y, en la propiedad OnStart, añadimos el siguiente código:
Concurrent(
ClearCollect(
colProyectos;
PROYECTOS
);
ClearCollect(
colTareas;
TAREAS
)
);;
Una vez ejecutado el código anterior, ya tendremos nuestros proyectos y tareas almacenados en dos colecciones (colProyectos y colTareas). A partir de este momento, vamos a trabajar con estas colecciones para realizar los filtros, los recuentos y los cálculos que necesitaremos en nuestra aplicación.
Una pequeña aclaración: aunque trabajar con colecciones nos permite evitar los problemas de delegación en los cálculos, debemos tener en cuenta que la carga inicial mediante ClearCollect está sujeta al límite de registros de Power Apps. En nuestro ejemplo, como estamos trabajando con 4 proyectos y 40 tareas, no tendremos ningún problema.
Añadimos una galería vertical (Gallery1) y, en la propiedad Items, introducimos el siguiente código:
AddColumns(
colProyectos As p;
Avance;
With(
{
tareasProyecto: Filter(
colTareas;
CodigoProyecto = p.CodigoProyecto
)
};
If(
IsEmpty(tareasProyecto);
0;
CountIf(
tareasProyecto;
Estado = "Completada"
) / CountRows(tareasProyecto)
)
)
)
Lo que estamos haciendo mediante AddColumns() es añadir una nueva columna, que hemos llamado Avance, a nuestra tabla de proyectos.
Para calcular su valor, utilizamos With() para almacenar temporalmente las tareas que corresponden a cada proyecto. A continuación, contamos las tareas que tienen el estado «Completada» y dividimos ese número entre el total de tareas del proyecto.
De esta forma, si tenemos un proyecto con 10 tareas y 8 de ellas están completadas, el valor de Avance será 0,8, es decir, un 80 %.
También hemos contemplado la posibilidad de que un proyecto no tenga todavía ninguna tarea. En ese caso, devolvemos un valor de cero para evitar una división entre cero.
A continuación, vamos a configurar los elementos que tenemos dentro de la galería.
Etiqueta del nombre del proyecto (Title1)
Esta etiqueta nos permitirá mostrar el nombre del proyecto y seleccionarlo al pulsar sobre ella.
Configuramos las siguientes propiedades:
Text: ThisItem.Title
OnSelect: Select(Parent)
De esta forma, al pulsar sobre el nombre de un proyecto, seleccionaremos el registro correspondiente de la galería. No necesitamos, por tanto, la flecha que aparece por defecto, ni tampoco la imagen, por lo que podemos eliminar ambos elementos.
Etiqueta del porcentaje de avance (Subtitle1)
Vamos a utilizar la etiqueta del subtítulo para mostrar el porcentaje de avance de cada proyecto.
En la propiedad Text escribimos:
Text(
ThisItem.Avance * 100;
"0"
) & "%"
Recordad que el campo Avance devuelve un valor comprendido entre 0 y 1, por lo que multiplicamos su valor por 100 y añadimos el símbolo del porcentaje.
Creamos las barras de progreso dinámicas
Y llegamos a una de las partes más interesantes de este ejemplo.
Para crear nuestras barras de progreso no vamos a necesitar ningún componente especial. Simplemente vamos a utilizar dos rectángulos dentro de la propia galería de proyectos.
El primero será el fondo de nuestra barra y el segundo representará el porcentaje de avance.
Rectángulo de fondo (rectFondoBarra)
Añadimos un rectángulo dentro de Gallery1 y configuramos las siguientes propiedades:
X: 22
Y: 48
Width: Parent.TemplateWidth - 110
Height: 10
Fill: ColorValue("#E5E7EB")
Este rectángulo será de color gris y representará siempre el recorrido completo de nuestra barra de progreso.
Rectángulo de avance (rectBarraAvance)
Añadimos un segundo rectángulo, también dentro de la galería, y lo situamos encima del anterior.
Configuramos las siguientes propiedades:
X: rectFondoBarra.X
Y: rectFondoBarra.Y
Height: rectFondoBarra.Height
Width: rectFondoBarra.Width * ThisItem.Avance
Fill:
Switch(
true;
ThisItem.Avance < 0,3;
ColorValue("#DC6868");
ThisItem.Avance < 0,7;
ColorValue("#E5AE38");
ColorValue("#249B75")
)
Como podéis observar, estamos utilizando las propiedades del rectángulo de fondo para situar el segundo rectángulo exactamente encima del primero.
Pero la propiedad más importante es Width. Mediante esta fórmula conseguimos que el ancho del segundo rectángulo sea proporcional al porcentaje de avance del proyecto.
Por ejemplo, si nuestro rectángulo de fondo tiene una anchura de 400 píxeles y el proyecto tiene un avance del 80 %, el segundo rectángulo tendrá una anchura de 320 píxeles.
Además, mediante la función Switch() hemos establecido tres colores diferentes en función del porcentaje de avance:
- Rojo: cuando el avance sea inferior al 30 %.
- Amarillo: cuando el avance sea igual o superior al 30 % e inferior al 70 %.
- Verde: cuando el avance sea igual o superior al 70 %.
Evidentemente, podéis modificar estos porcentajes y colores según vuestras necesidades.
Y con esto ya tenemos nuestras barras de progreso. Como los rectángulos están dentro de la galería, Power Apps se encarga de repetirlos para cada proyecto, calculando de forma independiente su anchura y su color.

Ahora vamos a añadir una segunda galería vertical (galTareas), que nos permitirá visualizar todas las tareas del proyecto que seleccionemos en la primera galería.
En la propiedad Items de galTareas escribimos:
Filter(
colTareas;
CodigoProyecto = Gallery1.Selected.CodigoProyecto
)
Como podéis ver, estamos utilizando el campo CodigoProyecto para relacionar los registros de ambas colecciones.
Cada vez que pulsemos sobre el nombre de un proyecto en Gallery1, se mostrarán automáticamente sus tareas en galTareas.
Dentro de esta segunda galería vamos a eliminar la imagen, la flecha y la etiqueta del subtítulo que aparecen por defecto. Conservaremos únicamente la etiqueta que muestra el nombre de la tarea y añadiremos un desplegable para modificar su estado.
Etiqueta del nombre de la tarea (lblNombreTarea)
Configuramos las siguientes propiedades:
Text: ThisItem.Title
X: 12
Y: 0
Width: ddEstado.X - Self.X - 12
Height: 60
Size: 11
La propiedad Width nos permite ajustar el ancho de la etiqueta al espacio disponible, dejando sitio a la derecha para el desplegable que vamos a crear a continuación.
Desplegable del estado de la tarea (ddEstado)
Añadimos un desplegable clásico (Drop down) dentro de galTareas. Este será el elemento que utilizaremos para modificar el estado de cada tarea.
Configuramos las siguientes propiedades:
Items:
["Pendiente"; "En curso"; "Completada"]
Default: ThisItem.Estado
Width: 155
Height: 34
X: Parent.TemplateWidth - Self.Width - 12
Y: 13
Size: 11
Fill:
Switch(
Self.Selected.Value;
"Completada"; ColorValue("#E3F4EA");
"En curso"; ColorValue("#FFF1D3");
"Pendiente"; ColorValue("#FCE4E4");
Color.White
)
Mediante la propiedad Items establecemos los tres posibles estados de nuestras tareas y, con Default, mostramos el estado que tiene actualmente cada registro.

Además, vamos a dar un poco de color a nuestra aplicación mediante la propiedad Fill, asignando un color diferente a cada uno de los estados.
Hasta este momento hemos conseguido mostrar nuestros proyectos, sus tareas y sus correspondientes barras de progreso.
Pero ahora queremos que, cuando modifiquemos el estado de una tarea, se actualice automáticamente el porcentaje de avance del proyecto.
Para ello, tenemos que realizar dos operaciones: guardar el nuevo estado en nuestra lista de SharePoint (TAREAS) y actualizar ese mismo registro en nuestra colección local (colTareas).
Seleccionamos el desplegable (ddEstado) y, en su propiedad OnChange, introducimos el siguiente código:
With(
{
idTarea: ThisItem.ID;
nuevoEstado: Self.Selected.Value
};
IfError(
With(
{
tareaGuardada: Patch(
TAREAS;
LookUp(
TAREAS;
ID = idTarea
);
{
Estado: nuevoEstado
}
)
};
UpdateIf(
colTareas;
ID = idTarea;
{
Estado: tareaGuardada.Estado
}
);;
true
);
Notify(
"No se ha podido actualizar la tarea";
NotificationType.Error
);;
false
)
);;
Vamos a ver qué estamos haciendo en este código.
En primer lugar, mediante With() almacenamos temporalmente el ID de la tarea y el nuevo estado seleccionado en el desplegable.
A continuación, utilizamos LookUp() para localizar el registro correspondiente en la lista TAREAS de SharePoint y Patch() para modificar su estado.
Si la operación se realiza correctamente, actualizamos también ese mismo registro en nuestra colección colTareas mediante UpdateIf().
Y si se produce algún error durante la actualización, mostramos una notificación mediante IfError().
¿Por qué actualizamos también la colección?
Porque todos los cálculos de nuestra aplicación se realizan sobre colTareas. Si únicamente modificásemos el registro en SharePoint, nuestra colección conservaría el valor anterior y las barras de progreso no reflejarían ese cambio hasta volver a cargar los datos.
Al actualizar la colección conseguimos que Power Apps recalcule automáticamente la columna Avance que hemos creado en la propiedad Items de la galería de proyectos.
Y, como las barras dependen de esa columna, tanto su anchura como su color se actualizarán automáticamente.
"Tareas de: " & Gallery1.Selected.Title
Una vez que tenemos funcionando las dos galerías, vamos a añadir tres indicadores en la parte superior de nuestra aplicación.
Estos indicadores nos mostrarán el número total de proyectos, las tareas completadas y el porcentaje de avance global.
Número total de proyectos (lblTotalProyectos)
Añadimos una etiqueta y en la propiedad Text escribimos:
CountRows(colProyectos)
De esta manera mostramos el número total de registros que tenemos en nuestra colección de proyectos.
Tareas completadas (lblTotalCompletadas)
Añadimos una segunda etiqueta y en su propiedad Text escribimos:
CountIf(
colTareas;
Estado = "Completada"
) & " / " & CountRows(colTareas)
Con esta fórmula contamos las tareas que están completadas y mostramos ese valor junto con el número total de tareas.
En nuestro ejemplo, el resultado inicial será 25 / 40.
Porcentaje de avance global (lblAvanceGlobal)
Y finalmente añadimos una tercera etiqueta para mostrar el porcentaje de avance global.
En la propiedad Text escribimos:
If(
IsEmpty(colTareas);
"0%";
Round(
CountIf(
colTareas;
Estado = "Completada"
) / CountRows(colTareas) * 100;
1
) & "%"
)
Y con esto ya tenemos nuestra aplicación PROJECT TRACKER.
Hemos creado un cuadro de seguimiento de proyectos utilizando dos listas de SharePoint, dos colecciones, dos galerías y unos cuantos controles de Power Apps.

Aunque cada vez que modificamos una tarea estamos actualizando SharePoint y nuestra colección, puede ocurrir que otro usuario modifique los datos directamente en SharePoint.
Para poder recuperar esos cambios, vamos a añadir un botón (btnActualizar).
Configuramos las siguientes propiedades:
Text: "Actualizar"
OnSelect:
Concurrent(
Refresh(PROYECTOS);;
ClearCollect(
colProyectos;
PROYECTOS
);
Refresh(TAREAS);;
ClearCollect(
colTareas;
TAREAS
)
);;
Mediante Refresh() actualizamos los orígenes de datos y, a continuación, volvemos a cargar la información en nuestras dos colecciones.
De esta manera podemos mantener actualizados los datos de la aplicación sin necesidad de cerrarla y volver a abrirla.
