FÓRMULAS PARA INDICAR SI UN VALOR EXISTE EN UN RANGO

Hola a todos:

Aunque en esta web suelo publicar muchos contenidos basados en programación VBA, también me gusta dar protagonismo a las fórmlas de Excel. Y es que en muchas (muchísimas) ocasiones, una fórmula puede ser más efectiva que usar código, ya sea por tiempo, por hábito, etc. El saber utilizarlas y combinarlas, hacen que sean una alternativa al uso de macros (aunque para algunos ejercicios concretos solo la programación nos puede ayudar).

Por lo tanto, hoy me gustaría contestar a la pregunta: ¿Qué fórmulas puedo usar para indicar que un valor está en un rango determinado de celdas?.

Pues bien, existen varias fórmulas para hacerlo, algunas con restricciones como que solo funcionan con datos numéricos o que solo es posible utilizar una columna como rango de búsqueda y otras que realizar el trabajo sin los límites comentados.

Aunque seguramente podría desarrollar otras fórmulas más complejas, finalmente me quedo con 9 métodos para realiza este trabajo. Vamos a ver en detalle cada una de ellos 🙂

Imaginad que tenéis dos columnas, una denominada RANGO y otra denominada DATO, y lo que queremos es utilizar una función que nos permita indicar cuáles son los valores de la columna DATO que se encuentran en la columna RANGO y en caso de existir coincidencia pondremos un “SI” y si no están un “NO” en la columna FÓRMULA:

FORMULAS PARA INDICAR SI UN VALOR EXISTE EN UN RANGO

También os especificaré si el rango de búsqueda puede aplicarse en varias columnas o únicamente funciona seleccionando una única columna.

Para el primer ejemplo vamos a utilizar las funciones CONTAR.SI y SI, que nos van a permitir contar las veces que el valor buscado se repite en la columna RANGO  por lo tanto, si es mayor que cero indicamos “SI”, de lo contrario será “NO”. El rango de búsqueda pueden ser varias columnas:

=SI(CONTAR.SI($A$4:$A$11;B4)>0;"SI";"NO")

En el segundo ejemplo vamos a usar las función COINCIDIR, SI y SI.ERROR de manera que si la posición del valor buscado al coincidir en el rango de búsqueda es mayor que cero indicará que existe y lo marcamos como un “SI”, de los contrario (si es un error) será “NO”. El rango de búsqueda debe ser una única columna:

=SI.ERROR(SI(COINCIDIR(F4;$E$4:$E$11;0)>0;"SI");"NO")

En el tercer ejemplo vamos a usar las funciones BUSCARV, SI y ESERROR. Usando BUSCARV buscamos el valor de DATO en la columna rango, si devuelve el mismo valor es que existe, por lo tanto indicamos un “SI”, si lo que devuelve es un error, marcamos un “NO”. El rango de búsqueda debe ser una única columna:

=SI(ESERROR(BUSCARV(J4;$I$4:$I$11;1;0));"NO";"SI")

En el cuarto ejemplo vamos usar las funciones SUMAPRODUCTO y SI. De forma que si la función SUMAPRODUCTO nos devuelve un valor mayor a 0 marcaremos “SI”, de lo contrario marcamos un “NO”. El rango de búsqueda pueden ser varias columnas:

=SI(SUMAPRODUCTO(($M$4:$M$11=N4)*1)>0;"SI";"NO")

En el quinto ejemplo vamos a usar las funciones SUMAR.SI y SI. La función SUMAR.SI en el momento que encuentre coincidencia sumará las veces que se repite dicho valor, si es mayor que 0 marcaremos que “SI”, en caso contrario marcamos “NO”. Esta función solo es válida si trabajamos con datos numéricos y permite que el rango de búsqueda puedan ser varias columnas:

=SI(SUMAR.SI($Q$4:$Q$11;R4;$Q$4:$Q$11)>0;"SI";"NO")

Como habéis visto, combinamos varias funciones para optener el resultado esperado. Al tener que codificar un “SI” o un “NO” (o cualquier indicativo que estimemos oportuno) nos fuerza a usar el SI condicional, que se usa en todas las funciones, y como algunas fórmulas arrojan error cuando no encuentran el dato, debemos usar las funciones ESERROR y SI.ERROR para controlar el error y codificar el valor que necesitamos.

Además de estas funciones, existe otra variante con funciones matriciales que también nos pueden ofrecer el mismo resultado. Os muestro cuatro posibilidades (las de rojo) y os recuerdo que las matrices se introducen: seleccionando la celda que contiene la fórmula, pulsando en F2, seleccionamos la fórmula y luego presionamos CTRL + MAYUS + ENTRAR

El sexto ejemplo es una fórmula matricial, usamos las funciones SI y O, determinando que si el valor buscado existe en el rango indicaremos un “SI” y en caso contrario un “NO”. Permite que el rango de búsqueda puedan ser varias columnas:

{=SI(O($A$17:$A$24=B17);"SI";"NO")}

El séptimo ejemplo es una variante de la fórmula matricial anterior, solo que combinamos con la función IGUAL, lo que nos va a permitir distinguir mayúsculas de minúsculas para búsquedas más exhaustivas. Permite que el rango de búsqueda puedan ser varias columnas:

{=SI(O(IGUAL($E$17:$E$24;F17));"SI";"NO")}

El octavo ejemplo es una fórmula (matricial) en la que usamos las funciones SI y SUMA de forma que sumamos las veces en las que aparece el valor en el rango de búsqueda. Si el valor es diferente de cero será verdadero y codificaremos “SI”, en caso contrario será falso y codificaremos “NO”. Permite que el rango de búsqueda puedan ser varias columnas:

{=SI(SUMA(($I$17:$I$24=J17)*1);"SI";"NO")}

La novena y última fórmula (matricial) combina las funciones SI y CONTAR. Cuando el valor que arroje la función sea mayor que cero indicará que el valor existe y por lo tanto marcamos un “SI”, en caso contrario un “NO”. Esta función solo es válida si trabajamos con datos numéricos y permite que el rango de búsqueda puedan ser varias columnas:

{=SI(CONTAR(SI(($M$17:$M$24=N17);$M$17:$M$24))>0;"SI";"NO")}

Como habéis podido observar, existen bastantes alternativas para saber si un valor está en un rango determinado, cada una con sus especificaciones para que podáis adaptarlas a vuestros trabajos y proyectos.

Por otra parte, en todos los casos podéis prescindir de las condiciones y las funciones de error para que veáis el resultado real que arroja la fórmula, de forma que algunas las podríais modificar para saber, por ejemplo, si el valor buscado se encuentra en el rango y si se repite varias veces (pero eso ya lo veremos en otro momento).

Es un post bastante extenso, pero creo que merece la pena hacerlo 🙂

Os dejo un archivo con el ejemplo de todas las fórmulas vistas y un resumen de algunas de sus características:

FORMULAS PARA INDICAR SI UN VALOR EXISTE EN UN RANGO2

Como siempre, espero que os sea de utilidad.

Descarga el archivo de ejemplo pulsando enFÓRMULAS PARA INDICAR SI UN VALOR EXISTE EN UN RANGO

 

Anuncios

ALGUNAS FÓRMULAS PARA CONFECCIONAR NUESTROS INFORMES EN EXCEL

Hola a todos:

En muchas de las consultas que recibo, un tema recurrente es el de la confección de informes. Normalmente siempre preguntas y referencias a las tablas dinámicas (campos calculados, orden de etiquetas, etc…).

Y es que realmente la función de las tablas dinámicas es esa: mostrar información dinámica en la confección informes.

Sin embargo, una buen alternativa a las tablas dinámicas es hacer nuestro informe utilizando fórmulas y siempre con la ventaja de que no vamos a depender de las limitaciones típicas de las tablas dinámicas (colocación de información, límites, etc).

Por ello, en el post de hoy me gustaría trabajar con algunas funciones que nos van a permitir realizar interesantes informes y sin necesidad de usar tablas dinámicas.

Utilizaremos una de las bases de datos que uso habitualmente como ejemplo, una plantilla ficticia de unos grandes almacenes (si quereis saber cómo he generado los nombres, podeís visitar este post: COMBINAR LA FUNCIÓN HALLAR Y LA FUNCIÓN LARGO)

Imaginad que tenemos esta base de datos:

ALGUNAS FORMULAS PARA CONFECCIONAR NUESTROS INFORMES EN EXCEL

Y necesitamos utilizar las fórmulas adecuadas para completar los datos de este informe (que ahora está vacío):

ALGUNAS FORMULAS PARA CONFECCIONAR NUESTROS INFORMES EN EXCEL_1

Para los campos de Sexo, Idioma y Estudios necesitamos funciones que cuenten y a su vez que admitan varios criterios de condición.

Para el campo de la edad necesitamos funciones que puedan obtener promedios, máximos y mínimos.

He creado cuatro hojas con el mismo informe, en cada una trabajaremos una fórmula distinta para contar.

En la hoja INFORME_SUMAPRODUCTO utilizaremos la función SUMAPRODUCTO, la cual vamos a modificar para que cuente los datos que necesitamos. Por ejemplo el número de Hombres en la sección de Deportes:

Solo tenemos que seleccionar un rango de la columna “C” (SECCION) de la Hoja BBDD y que sea igual a la celda A3 de nuestro informe (Deportes) e introducimos un segundo criterio, seleccionando la columna E de la hoja BBDD (SEXO) y la celda B2 de nuestro informe (Hombre).

=SUMAPRODUCTO((BBDD!$C$2:$C$65000=A3)*1;(BBDD!$E$2:$E$65000=$B$2)*1)

Para el resto de campos va a ser igual, excepto en IDIOMA (OTROS), donde debemos especificar que el idioma debe ser diferente de INGLES, FRANCES Y ALEMAN:

=SUMAPRODUCTO((BBDD!$C$2:$C$65000=A3)*1;(BBDD!$F$2:$F$65000<>$E$2)*1;(BBDD!$F$2:$F$65000<>$F$2)*1;(BBDD!$F$2:$F$65000<>$D$2)*1)

Como podéis observar, vamos introduciendo las condiciones de forma anidada y vinculando con el idioma que queremos excluir del proceso de contar empleados.

En la hoja INFORME_CONTAR.SI.CONJUNTO utilizaremos la función CONTAR.SI.CONJUNTO, presente desde Excel 2007 y es una buena opción para contar los elementos de nuestro informe. Siguiendo el ejemplo anterior (número de Hombres en la sección de Deportes) sería así:

=CONTAR.SI.CONJUNTO(BBDD!$C$2:$C$65000;A3;BBDD!$E$2:$E$65000;$B$2)

En la sintaxis seleccionamos rango de la columna SECCIÓN de la hoja BBDD y que sea igual a A3 y también seleccionamos la columna SEXO y que sea igual a B2 (Hombre).

Para el resto de campos va a ser igual, excepto en el IDIOMA (OTROS) donde usaremos la misma fórmula pero indicando los idiomas que no queremos que se tengan en cuenta:

=CONTAR.SI.CONJUNTO(BBDD!$C$2:$C$65000;A3;BBDD!$F$2:$F$65000;”<>” & $E$2;BBDD!$F$2:$F$65000;”<>” & $F$2;BBDD!$F$2:$F$65000;”<>” & $D$2)

Efectivamente usamos las clausulas <> para indicar que cuente aquellos que sea distintos de INGLES, FRANCES Y ALEMAN.

Pues bien, con cualquiera de estas fórmulas podríais realizar el informe perfectamente. Pero me gustaría dejaros otras dos fórmulas (matriciales) para realizar el mismo proceso:

En la hoja INFORME_MATRICIAL utilizaremos una matricial muy sencilla que realiza prácticamente el mismo trabajo que SUMAPRODUCTO (pero en matricial).

Usamos el mismo ejemplo que el de las fórmulas anteriores: Número de hombres en la sección “Deportes”:

{=SUMA((BBDD!$C$2:$C$65000=A3)*(BBDD!$E$2:$E$65000=$B$2))}

Y el resultado será el mismo que en las fórmulas anteriores, es decir 7.

El resto de campos será igual pero cambiando los parámetros, excepto en IDIOMA (OTROS), aquí tendremos que ampliar la fórmulas con más criterios:

{=SUMA((BBDD!$C$2:$C$65000=A3)*(BBDD!$F$2:$F$65000<>$E$2)*(BBDD!$F$2:$F$65000<>$F$2)*(BBDD!$F$2:$F$65000<>$D$2))}

Indicando qué idioma no queremos contar. Esta matricial, me parece muy sencilla y a la vez efectiva, es una de mis favoritas 🙂

En la hoja INFORME_MATRICIAL_2 utilizaremos otra matricial pero en la que usaremos la función CONTAR.

Para el cálculo del número de hombres en la sección “Deportes”, sería así:

{=CONTAR(SI((BBDD!$C$2:$C$65000=A3);SI(BBDD!$E$2:$E$65000=$B$2;BBDD!$A$2:$A$65000)))}

Sin embargo, esta fórmula tiene una peculiaridad, solo va a contar si el rango sobre el que se cuenta es numérico, en nuestro ejemplo podríamos hacer referencia a la columna A o a la D, en nuestro caso, he marcado la A en rojo en la fórmula. Por ello no la podréis usar si vuestra base de datos no tiene una columna con datos numéricos, tipo edad, ID, etc.

Para el contar las celdas de IDIOMA (OTROS), tendremos que incluir los criterios en la función, así:

{=CONTAR(SI((BBDD!$C$2:$C$65000=A3);SI(BBDD!$F$2:$F$65000<>$E$2;SI(BBDD!$F$2:$F$65000<>$F$2;SI(BBDD!$F$2:$F$65000<>$D$2;BBDD!$A$2:$A$65000)))))}

Y el resultado es el mismo para todos los casos:

ALGUNAS FORMULAS PARA CONFECCIONAR NUESTROS INFORMES EN EXCEL_2

Aunque no era el objeto de este post, os he incluido tres fórmulas más (matriciales) para calcular el promedio, el máximo y el mínimo de la edad por cada sección.

Para calcular el Promedio:

{=REDONDEAR(PROMEDIO(SI(BBDD!$C$2:$C$65000=A3;BBDD!$D$2:$D$65000));0)}

y usamos la función redondear para eliminar todos los decimales (podríamos usar entero).

Para el cálculo de Max:

{=REDONDEAR(MAX(SI(BBDD!$C$2:$C$65000=A3;BBDD!$D$2:$D$65000));0)}

Para el cálculo de Min:

{=REDONDEAR(MIN(SI(BBDD!$C$2:$C$65000=A3;BBDD!$D$2:$D$65000));0)}

El resultado es este (el mismo para las cuatro pestañas):

ALGUNAS FORMULAS PARA CONFECCIONAR NUESTROS INFORMES EN EXCEL_3

Y las cuatro pestañas tienen que mostrar la misma información.

ALGUNAS FORMULAS PARA CONFECCIONAR NUESTROS INFORMES EN EXCEL_4

Hemos utilizado fórmulas distintas para contar numero de empleados por sección o departamento, según sexo, idioma o estudios. Y también hemos calculado algunos estadísticos para enriquecer la información.

Os recuerdo que las matrices se introducen: seleccionando la celda que contiene la fórmula, pulsando en F2 , seleccionamos la fórmula y luego presionamos CTRL + MAYUS + ENTRAR

Descarga el archivo de ejemplo pulsando enALGUNAS FÓRMULAS PARA CONFECCIONAR NUESTROS INFORMES EN EXCEL