AGRUPAR INFORMACIÓN DE VARIOS LIBROS EN UNA HOJA EXCEL

En esta web ya llevo varios post dedicados al tema de agrupar o consolidar información en Excel, desde agrupar la información de varios archivos a una misma hoja a consolidar la información de todas las pestañas, estos son los post relacionados:

1 – CONSOLIDAR HOJAS DE UN LIBRO CON UNA CONSULTA SQL DE UNIÓN
2 – CONSOLIDAR INFORMACIÓN DE VARIOS ARCHIVOS EN UNA HOJA EXCEL
3 – CONSOLIDAR INFORMACIÓN DE VARIOS ARCHIVOS EN UNA HOJA EXCEL CON VBA

Y con este post de hoy creo que este tema quedará bastante documentado. Hace unos días, me solicitaron realizar una modificación en la macro del tercer post de la lista que acabo de comentar. La solicitud era que se pudiesen seleccionar los archivos que queremos agrupar en lugar de seleccionar una carpeta para agrupar todo el contenido. Aunque parezca un tema menor creo que es necesario comentar estas modificaciones.

El razón de realizar el post con la carpeta como fuente de los datos, fue por dos motivos: No hay muchas macros publicadas que lo hagan así y por otra parte, en procesos automatizados, es una solución más eficiente que tener que ir seleccionando los archivos. Pero, claro, se puede dar el caso que la información, precisamente, necesite ser agrupada seleccionando individualmente cada archivo que queremos agrupar.

Aprovecharé los archivos del post motivo de la consulta e introduciré algunos cambios en la programación.

Como siempre, imaginad que tenemos la siguiente carpeta con estos 3 archivos y queremos consolidar o agrupar toda la información en una hoja:

consolidar-informacion-de-varios-archivos-en-una-hoja-excel-con-vba1

Para hacerlo vamos a utilizar la siguiente macro:

Sub AGRUPAR_ARCHIVOS()
'Definimos variables
Dim i As Integer, j As Integer, FilaInicio As Integer
Dim iArchivo As String, nArchivo As String, MiLibro As String
Dim dir_Archivo As Variant
Dim iRango As Range, dRango As Range
Dim Hoja_Destino As Worksheet, iLibro As Workbook
'Creamos ventana de diálogo para seleccionar los archivos que queremos agrupar
On Error Resume Next
dir_Archivo = Application.GetOpenFilename(Title:="SELECCIONA ARCHIVOS PARA CONSOLIDAR", MultiSelect:=True, filefilter:="Excel files (*.xls*), *.xls*")
On Error GoTo 0
'Si no seleccionamos archivos, salimos del proceso
If Not IsArray(dir_Archivo) Then
Exit Sub
End If
'Si existen datos en la hoja AGRUPADO, los eliminamos
With ThisWorkbook.Sheets("AGRUPADO")
elimina = Application.CountA(.Range("A:A")) + 1
If elimina > 0 Then .Range("A1:A" & elimina).EntireRow.Delete
End With
'Iniciamos un for con para identificar los archivos seleccionados
If IsArray(dir_Archivo) Then
For j = LBound(dir_Archivo) To UBound(dir_Archivo)
nArchivo = dir_Archivo(j)
'Determinamos a partir de que fila vamos a consolidar los datos
FilaInicio = 1
'Desactivamos actualizacion de pantalla y eventos
With Application
.ScreenUpdating = False
.EnableEvents = False
End With
'Identificamos el nombre de nuestro libro
MiLibro = ThisWorkbook.Name
'Indicamos la hoja de destino de los datos que queremos consolidar
Set Hoja_Destino = ThisWorkbook.Sheets("AGRUPADO")
'Listamos los archivos Excel a consolidar
iArchivo = nArchivo
'Si la longitud del archivo es cero, salimos del proceso (no existe archivo para consolidar)
If Len(iArchivo) = 0 Then Exit Sub
'Si el nombre del archivo no es igual a nuestro libro seguimos el proceso
If Not iArchivo = MiLibro Then
'Capturamos ruta al iarchivo
Set iLibro = Workbooks.Open(Filename:=nArchivo)
'Contamos las hojas que tiene
fin = iLibro.Sheets.Count
'Iniciamos un bucle por cada hoja, donde seleccionamos los datos desde la fila 2
'hasta el final de la hoja (siempre sin filas en blanco)
'Luego copiamos los datos en la Hoja_Destino, que es la Hoja "AGRUPADO"
'Colocándolos al final de los rangos que se vayan pegando
For i = 1 To fin
iLibro.Sheets(i).Select
Set iRango = iLibro.Sheets(i).Range(Cells(FilaInicio, 1), Cells(Cells(Rows.Count, 1).End(xlUp).Row, Cells(1, Columns.Count).End(xlToLeft).Column))
Set dRango = Hoja_Destino.Range("A" & Hoja_Destino.Cells(Rows.Count, 1).End(xlUp).Row + 1)
iRango.Copy
With dRango
.PasteSpecial xlPasteValues
.PasteSpecial xlFormats
End With
Next
'Cerramos el libro y continuamos el proceso
Application.CutCopyMode = False
iLibro.Close False
End If
Next j
End If
With Application
.ScreenUpdating = True
.EnableEvents = True
End With
' Una vez finalizado, lanzamos mensaje de finalización.
MsgBox ("EL PROCESO HA FINALIZADO CORRECTAMENTE"), vbInformation, "PROCESO DE CONSOLIDACIÓN"
End Sub

Como podéis ver, hemos realizado algunas modificaciones en la macro anterior, entre ellas el tipo de cuadro de diálogo para seleccionar los archivos, con el método .GetOpenFilename y con la propiedad MultiSelect:=True, fundamental para seleccionar varios archivos:

AGRUPAR INFORMACION DE VARIOS LIBROS EN UNA HOJA EXCEL

Dado que estamos seleccionando varios archivos debemos especificar en el código el archivo qué vamos a procesar en cada momento, de ahí que debamos introducir un pequeño bucle indicando esta información, (utilizando matrices).

If IsArray(dir_Archivo) Then
For j = LBound(dir_Archivo) To UBound(dir_Archivo)
nArchivo = dir_Archivo(j)

El resto de la macro es idéntica a la que ofrecí en el post anterior al que nos estamos refiriendo.

Para este ejemplo, no he puesto encabezados de columna en la hoja “AGRUPADO”, de forma que los datos que vayamos a agrupar aparecerán con su encabezado en el resumen final (tal y como podéis ver aquí) este es el resultado de la macro:

AGRUPAR INFORMACION DE VARIOS LIBROS EN UNA HOJA EXCEL1

Cada encabezado representa la información extraída en cada hoja. Para eliminar los encabezados sobrantes con un simple filtro los podremos borrar (dejando el primero) y tendremos toda la información agrupada.

Si por el contrario, sabemos que todas las hojas tienen la misma estructura, con los mismos campos, podemos indicar el encabezado en la hoja “AGRUPADO”, pero entonces tendríamos que realizar las siguientes modificaciones en la macro (os dejo solo la parte que se modifica):

'Si existen datos en la hoja AGRUPADO, los eliminamos
With ThisWorkbook.Sheets("AGRUPADO")
elimina = Application.CountA(.Range("A:A")) 'eliminamos el +1
If elimina > 1 Then .Range("A2:A" & elimina).EntireRow.Delete
End With
'Iniciamos un for con para identificar los archivos seleccionados
If IsArray(dir_Archivo) Then
For j = LBound(dir_Archivo) To UBound(dir_Archivo)
nArchivo = dir_Archivo(j)
'Determinamos a partir de que fila vamos a consolidar los datos
FilaInicio = 2

El resultado sería el siguiente:

AGRUPAR INFORMACION DE VARIOS LIBROS EN UNA HOJA EXCEL2

Es decir, que podemos configurar el proceso según nuestras necesidades.

Es una macro con la que he disfrutado bastante escribiendo el código, ahora solo espero que os resulte de utilidad.

Descarga el archivo de ejemplo pulsando en: AGRUPAR INFORMACIÓN DE VARIOS LIBROS EN UNA HOJA EXCEL

Y la carpeta de ejemplo con los 3 archivos para realizar pruebas:  ARCHIVOS DE EJEMPLO PARA PRUEBAS

 

Anuncios

CONSOLIDAR INFORMACIÓN DE VARIOS ARCHIVOS EN UNA HOJA EXCEL CON VBA

Hola todos, ¿qué tal vais? ¡Seguro que bien! 🙂

Hoy me gustaría tratar un tema bastante recurrente cuando en nuestros procesos diarios trabajamos con cantidades bastante elevadas de archivos. Me refiero, por ejemplo, a que seamos los receptores de reportes diarios o mensuales de informaciones tipo, ventas, clientes, ingresos, etc.

Cuando sucede esto, solemos acabar con varias carpetas donde vamos almacenando la información por mes o por día y a la que habitualmente acudimos y confeccionamos nuestros reportes COPIANDO Y PEGANDO A MANO.

Esta situación la puedes tener un día, pero no debe darse habitualmente, por ello, he estado trabajando en un macro para resolver este problema.

Vamos a realizar un caso práctico, y vamos a utilizar nuestra base de datos de ejemplo, la del personal ficticio de unos grandes almacenes. En total son 180 empleados:

consolidar-informacion-de-varios-archivos-en-una-hoja-excel-con-vba

Para realizar un ejemplo, vamos a crear tres libros con tres hojas cada uno y en cada pestaña pegaremos 20 empleados y luego guardamos los archivos en una carpeta (CONSOLIDADO):

consolidar-informacion-de-varios-archivos-en-una-hoja-excel-con-vba1

La idea es que con mediante un proceso podamos juntar de nuevo todas las hojas en un único archivo.

Para configurar nuestra hoja vamos a crear dos pestañas, una que vamos a denominar “CONSOLIDAR”,  y otra, en la segunda hoja que vamos a denominar “AGRUPADO”.

En la primera hoja colocaremos un botón de acción para ejecutar la macro y la segunda nos servirá para agrupar toda la información.

Una vez realizado esto, ya podemos pegar la siguiente macro:

Sub CONSOLIDAR()
Dim path As String, MiLibro As String
Dim FilaInicio As Integer
Dim i As Integer
Dim iArchivo As String
Dim iRango As Range, dRango As Range
Dim Hoja_Destino As Worksheet, iLibro As Workbook
'Creamos ventana de diálogo para seleccionar ruta al directorio o carpeta
On Error Resume Next
With CreateObject("shell.application")
path = .browseforfolder(0, Titulo, 0).Items.Item.path
End With: On Error GoTo 0
If path = Empty Then
Exit Sub
End If
'Determinamos a partir de que fila vamos a consolidar los datos
'Normalmente fila 2 si tenemos encabezados de columna
FilaInicio = 2
'Desactivamos actualizacion de pantalla y eventos
With Application
.ScreenUpdating = False
.EnableEvents = False
End With
'Identificamos el nombre de nuestro libro
MiLibro = ThisWorkbook.Name
'Limpiamos datos en la hoja "AGRUPADO" para actualizar la informacion
ThisWorkbook.Sheets("AGRUPADO").Range("A2:H65000").ClearContents
'Indicamos la hoja de destino de los datos que queremos consolidar
Set Hoja_Destino = ThisWorkbook.Sheets("AGRUPADO")
'Identificamos y listamos los archivos Excel en el directorio (por orden de fecha de modificación)
iArchivo = Dir(path & "\*.xl*", vbNormal)
'Si la longitud del archivo es cero, salimos del proceso (no existe archivo para consolidar)
If Len(iArchivo) = 0 Then Exit Sub
' Mientras el largo del archivo sea mayor de 0 iniciamos el proceso
Do While Len(iArchivo) > 0
'Si el nombre del archivo no es igual a nuestro libro seguimos el proceso
If Not iArchivo = MiLibro Then
'Capturamos ruta al iarchivo
Set iLibro = Workbooks.Open(Filename:=path & "\" & iArchivo)
'Contamos las hojas que tiene
fin = iLibro.Sheets.Count
'Iniciamos un bucle por cada hoja, donde seleccionamos los datos desde la fila 2
'hasta el final de la hoja (siempre sin filas en blanco)
'Luego copiamos los datos en la Hoja_Destino, que es la Hoja "AGRUPADO"
'Colocándolos al final de los rangos que se vayan pegando
For i = 1 To fin
iLibro.Sheets(i).Select
Set iRango = iLibro.Sheets(i).Range(Cells(FilaInicio, 1), Cells(Cells(Rows.Count, 1).End(xlUp).Row, Cells(1, Columns.Count).End(xlToLeft).Column))
Set dRango = Hoja_Destino.Range("A" & Hoja_Destino.Cells(Rows.Count, 1).End(xlUp).Row + 1)
iRango.Copy
dRango.PasteSpecial xlPasteValues
Next
'Cerramos el libro y continuamos el proceso
Application.CutCopyMode = False
iLibro.Close False
End If
iArchivo = Dir()
Loop
' Si queremos podemos ordenar la información consolidada, en este caso por ID.
' Podemos obviar esta parte si no necesitamos ordenar los datos.
With ThisWorkbook.Sheets("AGRUPADO")
D_fin = Application.CountA(.Range("A:A"))
.Range("A1:G" & D_fin).Sort Key1:=Range("A1"), Order1:=xlAscending, Header:= _
xlGuess, OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom, _
DataOption1:=xlSortNormal
.Range("A1").Select
.Columns.AutoFit
End With
With Application
.ScreenUpdating = True
.EnableEvents = True
End With
' Una vez finalizado, lanzamos mensaje de finalización.
MsgBox ("EL PROCESO HA FINALIZADO CORRECTAMENTE"), vbInformation, "PROCESO DE CONSOLIDACIÓN"
End Sub

Como podéis observar, he incluido un buscador de directorios o carpetas de forma que no sea necesario modificar la macro para hacer referencia a la ruta de los archivos.

With CreateObject("shell.application")
path = .browseforfolder(0, Titulo, 0).Items.Item.path

Tan solo hay que seleccionar la carpeta donde los hemos guardado. El resto de la macro, lo voy explicando en el propio archivo.

Sí que me gustaría comentar lo siguiente, para indexar los archivos tipo Excel (*xl*) que vamos a consolidar he utilizado la función Dir().

iArchivo = Dir(path & "\*.xl*", vbNormal)

Efectivamente, lista los archivos que iremos procesando y lo hace correctamente. Sin embargo, en caso que necesitásemos que se fueran procesando ordenados por nombre, no podríamos hacerlo, la función ordena según la fecha de modificación del archivo, de la más antigua a la más reciente. Por ello, si los archivos que queremos consolidar han de llevar un cierto orden se debe tener en cuenta la fecha de modificación.

Para solucionar esta limitación de la función DIR(), al final de la macro, he añadido una pequeña instrucción que nos ordenará la hoja “AGRUPADO” por, por ejemplo, el ID. Y así tendremos los datos en orden.

Si no necesitáis que estén ordenados, simplemente elimináis la última parte:

D_fin = Application.CountA(.Range("A:A"))
.Range("A1:G" & D_fin).Sort Key1:=Range("A1"), Order1:=xlAscending, Header:= _
xlGuess, OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom, _
DataOption1:=xlSortNormal

Pues esta ha sido la entrada de hoy, espero que os resulte de tanta utilidad como a mi (y os ahorre tiempo).

Importante: Este archivo de ejemplo está guardado como .xls y consolidará archivos que sean .xls. Si los archivos a consolidar son .xlsx es necesario guardar este archivo como .xslm. Esto es debido a la diferencia entre el número de filas permitido entre la versión 2003 y 2007 en adelante.

Os dejo el archivo de la macro.

Descarga el archivo de ejemplo pulsando en: CONSOLIDAR INFORMACIÓN DE VARIOS ARCHIVOS EN UNA HOJA EXCEL CON VBA

Y aquí la carpeta de ejemplo con los 3 archivos (esta en Drive, dado que en WordPress no se permite subir carpetas al servidor):  ARCHIVOS DE EJEMPLO PARA PRUEBAS